;1D CODEX
;modified based on the pulsprogram from Mei Hong's webpage
;by Johanna Becker-Baldus, AK Glaubitz, BMRZ Frankfurt
;contact j.baldus@em.uni-frankfurt.de
;Lit: D. Reichert et al., J. Magn. Resn. 151, 2000, 129-135 (here the extended phase cycle is described)
;Lit: E.R. deAzevedo et al., JACS 121, 1999, 8411-8412 

; Use a trigger Signal from the MAS unit
; To set up a series of experiments use au programm set_codex

;d1     : recycle delay
;p3     : 1H 90
;pl3    : 1H 90 power
;p1     : X 90
;pl1    : X 90 power
;p15    : CP time
;pl11   : X CP power
;pl22   : 1H CP power (shape)
;spf0   : shape 1H CP
;cnst31 : spinning speed in Hz
;d20    : 1/4 rotor period
;d2     : mixing time (multiple of rotor period)
;d4     : 1st z-Filter
;d5     : 2nd z-Filter (calculated from d6 and d2)
;d28    : exitation time (only for info not used by pp)
;l0     : loop counter, even number
;d6		: total time (mixing + 2nd z-Filter)
;ns     : multiple of 128

"acqt0=1u*cnst11"
"p2=p1*2"
"d20=0.25s/cnst31" 
"d21=d20-p2/2" 
"d28=1.0s*((l0/2)+1)/cnst31"
"d0=1u"
"d4=3m"
"d5=d6-d2"


; SAFETY CATCHES: 
if "p15<10.1m" goto Passp15               ; make sure contact time stays < 10 ms
  print "contact time exceeds 10 ms limit!"
  goto HaltAcqu
  Passp15, 1m

if "aq<50.1m" goto Passaq                 ; make sure aquisition time < 50 ms
  print "acquisition time exceeds 50 ms limit!"
  goto HaltAcqu
  Passaq, 1m
  
1 ze
  d28
2 1m do:f2
  d1 do:f2
 (p3 pl3 ph1):f2
  1u
 (p15 pl11 ph2):f1 (p15:spf0 pl22 ph10):f2
 d0
 (p1 pl1 ph4):f1
 d4
 trigpe4
 1u cpds2:f2 
 (p1 pl1 ph5):f1

 d20
 d21
 (p2 pl1 ph12):f1
 d21
3 d21
  (p2 pl1 ph12):f1
  d21
lo to 3 times l0
 d20
 
 (p1 pl1 ph6):f1
 1u do:f2
 d2 
 trigpe4
 1u cpds2:f2 
 (p1 pl1 ph7):f1
 
 d20
 d21
 (p2 pl1 ph12):f1
 d21
4 d21
  (p2 pl1 ph12):f1
  d21
lo to 4 times l0
 d20

 (p1 pl1 ph8):f1
 1u do:f2
 d5
 (p1 pl1 ph9):f1
 3u
 go=2 ph31 cpds2:f2
 1m do:f2
 30m wr #0

 HaltAcqu, 1m

 exit

ph1 = 0 2 
ph2 = 0 
ph4 = 1 ;store0
ph5 = 3 ;read0
ph6 = {3}*8 {2}*8 {1}*8 {0}*8 ;store1
ph7 = {1}*8 {0}*8 {1}*8 {0}*8 {3}*8 {2}*8 {3}*8 {2}*8 {2}*8 {1}*8 {2}*8 {1}*8 {0}*8 {3}*8 {0}*8 {3}*8 ;read1
ph8 = {3}*64 {2}*64 ;store2
ph9 = {1 1 2 2 3 3 0 0}*16  ;read2
ph10= 1 
ph12= 0 1 0 1 1 0 1 0 ;xy-8
ph31= 0 2 1 3 2 0 3 1
      0 2 1 3 2 0 3 1
      2 0 3 1 0 2 1 3
      2 0 3 1 0 2 1 3
      2 0 3 1 0 2 1 3
      2 0 3 1 0 2 1 3
      0 2 1 3 2 0 3 1
      0 2 1 3 2 0 3 1