; pFbihsqcf2.31pedit
; 22 22 000 00000
; -----------------
; 13C-31P HCP (13C-HSQC with 31P-editing), with bird pulse
; option for 31P-evolution (evop)
; assuming 13C on f2 and 31P on f3

; ds : 4
; ns : 4*n
; -----------------
; Peter Schmieder/ Monika Beerbaum, 22.01.2014
;_________________________________
; P. Schmieder; F. Nitschke; M. Steup; K. Mallow; E. Specker 
; "Determination of Glucan Phosphorylation using Heteronuclear 1H,13C Double
; and 1H,13C,31P Triple Resonance NMR Spectroscopy"
; Magn. Reson. Chem. 51, 655-661 (2013)

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

prosol relations=<fmp_2011_basic>

"in0 = inf1/2"

"p2 = p1*2.0"
"p4 = p3*2.0"
"p6 = p5*2.0"

# ifdef evop
"d0 = (cnst0*in0 - 1.28*p5 - p4)/2"
# else
"d0 = (cnst0*in0 - 1.28*p3 - p6)/2"
# endif /*evop*/

"d11 = 30m"
"d12 = 20u"
"d13 = 3u"

"TAU = cnst1*3.5m"
"TAU1 = TAU/2.0"

"DELTA = cnst25*12.5m - p60 - d60 - 50u"

1 ze
2 d17 do:f2
  d12 pl2:f2
;---- start BIRD ----------------------
  p1 ph1
  TAU
  (center (p2 ph1):f1 (p4 ph1):f2)
  TAU 
  p1 ph9
  d19
;---- start H,C-INEPT -----------------
  p1 ph1
  TAU1
  (center (p2 ph1):f1 (p4 ph1):f2)
  TAU1
  (p1 ph2)
  50u UNBLKGRAD
  p61:gp22
  d61
;---- start C,P-INEPT -----------------
  (p3 ph3):f2
  DELTA
  50u
  p60:gp20
  d60
  (center (p4 ph1):f2 (p6 ph1):f3)
  50u
  p60:gp20
  d60
  DELTA
  (p3 ph2):f2
  50u
  p61:gp22
  d61
;---- start evolution ----------------
# ifdef evop
  (p5 ph15):f3
  d0
  (center (p2 ph1):f1 (p4 ph1):f2)
  d0 
  (p5 ph16):f3
# else
  (ralign (p3 ph5):f2 (p5 ph15):f3)
  d0
  (center (p2 ph1):f1 (p6 ph1):f3)
  d0 
  (p3 ph1):f2 (p5 ph16):f3
# endif /*evop*/
  50u
  p61:gp22
  d61
;---- start C,P-INEPT -----------------
  (p3 ph2):f2
  DELTA
  50u
  p60:gp20
  d60
  (center (p4 ph1):f2 (p6 ph1):f3)
  50u
  p60:gp20
  d60
  DELTA
  (p3 ph4):f2
  45u
  p61:gp22
  d61
  5u BLKGRAD
;---- start H,C-INEPT -----------------
  (p1 ph2):f1
  TAU1
  d13
  (center (p2 ph1):f1 (p4 ph1):f2)
  d13
  TAU1 pl12:f2
8 go=2 ph31 cpd2:f2
  d11 do:f2 mc #0 to 2
# ifdef evop
      F1PH(ip15, id0)
# else
      F1PH(ip5, id0)
# endif /*evop*/

exit

ph1 = 0
ph9 = 2

ph2 = 1
ph3 = 0 0 2 2
ph4 = 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2

ph5 = 0

ph15 = 0 2 
ph16 = 0 0 0 0 2 2 2 2

ph31 = 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0



;PARAMETER

;__________Pulses__________

;p1 :90deg high power pulse f1 (pl1)
;p2 :180deg high power pulse f1 (pl1)
;p3 :90deg high power pulse f2 (pl2)
;p4 :180deg high power pulse f2 (pl2)
;p5 :180deg high power pulse f3 (pl2)
;p6 :90deg high power pulse f3 (pl2)

;_________power level for hard pulses_________

;pl1 :high power for protons f1
;pl2 :high power for 13C f2
;pl3 :high power for 31P f3

;__________Gradients_________

;p60:gradient pulse [200 usec]
;d60:recovery for gradient p60 [100 usec]
;p61:gradient pulse [1 msec]
;d61:recovery fpr gradient p61 [500 usec]
;gpz20 :power for clean gradient [10%]
;gpnam20 :shape for gradient p60 [SINE.20]
;gpz22 :power for crusher gradient [40%]
;gpnam22 :shape for gradient p61 [SINE.100]

;__________decoupling__________

;pcpd2 :90 deg 13C decoupling pulse (pl12)
;cpdprg2 :decoupling sequence in f2 [garp]
;pl12 :power for 13C cpd-decoupling f2

;_________delays_________

;d0 :incremented delay (2D)
;d17 :relaxation delay          [259 msec]
;d19 :delay for BIRD pulse      [198 msec]
;d11 :delay for disk I/O        [30 msec]
;d12 :delay for power switching [20 usec]
;d13 :short delay               [ 3 usec]
;TAU :1/(2J) HC
;TAU1 :1/(4J) HC
;DELTA:1/(4J) CP

;__________constants__________

;cnst0 :!!!!! scaling for first point ind. dim !!!!!
;cnst1 :scaling for 1/(2J) HC (TAU)
;cnst25 : scaling for 1/(2J) CP (DELTA)

;__________options_________

;zgoptns :-Devop   31P evolution